数码之家

 找回密码
 立即注册
搜索
查看: 8087|回复: 35

[C51] TM1637显示模块,EC11编码器,电风扇长定时+自然风汇编程序

  [复制链接]
发表于 2020-7-11 00:28:17 | 显示全部楼层 |阅读模式

爱科技、爱创意、爱折腾、爱极致,我们都是技术控

您需要 登录 才可以下载或查看,没有账号?立即注册

x
电风扇定时时间60分钟觉得短了些,如果一直开的话,吹到天亮人也难受,能定时三四小时比较合适,手头上有若干闲置了十余年的STC89C51RC,所以就用它来制作个长定时器,使用EC11带开关旋转编码器调时间,很便宜,一块多钱一只还包邮,也可以用按键代替编码器,只是调时间的时候不如编码器那么方便快捷,显示用TM1637四位数码管显示模块,3块钱包邮,便宜又好用,它能显示到99小时,所以最长定时可达99小时59分59秒,虽然实际使用不需要那么长的定时。制作好后不对电风扇作任何改动,只是把双向可控硅的T1、T2分别与原定时器那两根线接好就可以了,也就是与原定时器并联,把原定时器调到OFF位置。单片机改用其他型号的话,需要改动一些地方,如EEPROM操作、扇区地址、数量、特殊功能寄存器地址、看门狗预分频数等等

电路接线图.JPG

  1. ;TM1637显示模块,EC11编码器,电风扇长定时+自然风汇编程序
  2. ;杨小强,2020年6月
  3. ;单片机:STC89C51RC,晶振:11.0592MHz
  4. ;显示:(TM1637)4位数码管显示模块
  5. ;调整、设置:EC11带开关5脚旋转编码器,也可以用按键代替
  6. ;电源:闲置5V手机充电器
  7. ;
  8. ;最长定时99小时59分59秒,简单的采用间歇通/断电方式模拟自然风,周期可调,用可控硅控制通断。
  9. ;
  10. ;按编码器开关1次:正常/自然风切换,自然风状态时LED指示灯亮,可控硅间歇通断电
  11. ;按编码器开关2次:定时时间清零,风扇电机断电,两次按键动作之间不大于0.6秒
  12. ;
  13. ;长按编码器开关5秒以上15秒以内,松开按键后进入设置状态,退出设置状态:设置完第五项后按编码器开关、或任意一
  14. ;项中停15秒无任何操作,就自动保存并退出。根据数码管左边显示的数字进行以下各项设置,通过旋转编码器加或减,
  15. ;按编码器开关进入下一项设置:
  16. ;一、显示1——设置自然风状态时,通断电周期时长,5~30秒,默认为10秒
  17. ;二、显示2——设置自然风时电机通电时长,最短为2秒;最长为上一项所设的周期减3秒,比如上一项设置的周期为10秒,
  18. ;             则本项最多可以设置到7秒;
  19. ;三、显示3——设置3小时以下定时调整时,编码器每转动一格的增(减)值:5、10、15、20、25、30分钟,默认10分钟,
  20. ;             3小时以上增(减)值30分钟;10小时以上增(减)值1个小时;20小时以上增(减)值2个小时
  21. ;四、显示4——设置电风扇插电就自动填入的定时时间,0~30小时,默认8小时
  22. ;五、显示5——设置数码管亮度,1~8级,默认为3级
  23. ;
  24. ;长按编码器开关15秒:恢复各项默认设置,数码管显示88:88
  25. ;
  26. ;设置保存失败显示5秒E1
  27. ;
  28. ;--------------------------- 端口定义 ---------------------------
  29.         CLK        EQU P1.5   ;接显示模块TM1637的CLK
  30.         DIO        EQU P1.6   ;接显示模块TM1637的DIO
  31.         EC11A        EQU P3.2   ;接编码器的A引脚,外部中断INT0,也可以接一个按键代替
  32.         EC11B        EQU P3.3   ;接编码器的B引脚,外部中断INT1,也可以接一个按键代替
  33.         EC11K        EQU P3.4   ;接编码器的按键开关引脚
  34.         RLED        EQU P0.4   ;只要发生过复位就一直保持低电平,如有需要可接上LED方便观察
  35.         LED        EQU P0.5   ;自然风状态LED指示灯,低电平亮
  36.         MOC        EQU P0.7   ;接MOC3022光控可控硅,低电平时风扇电机通电

  37. ;--------------------------- 位地址及RAM的使用 ---------------------------
  38. ;(20H)第0位:1=编码器已经转动,等待主程序处理,0=没有转动或主程序已处理
  39. ;(20H)第1位:1=编码器顺时针正转;0=编码器逆时针反转
  40. ;(20H)第2位:1=自然风状态;0=正常状态
  41. ;(20H)第3位:1=禁止;0=允许。进行各项设置时使用,允许/禁止检查剩余时间
  42. ;(20H)第4位:1=闪烁显示;0=不闪烁。进行各项设置时用
  43. ;(20H)第5位:1=不显示,0=显示,数字及冒号闪烁时用,由T0中断每0.5秒取反一次
  44. ;(20H)第6位:1=显示3秒88:88;0=正常
  45. ;(20H)第7位:1=显示5秒E1;0=正常

  46.         FWBZ1        EQU        022H        ;复位判断标志1,也作EEPROM数据判断标志
  47.         FWBZ2        EQU        023H        ;复位判断标志2,也作EEPROM数据判断标志
  48.         ZRFZQ        EQU        024H        ;自然风时通断电周期时长
  49.         ZRFSJ        EQU        025H        ;自然风时电机通电时长
  50.         BMQZJ        EQU        026H          ;编码器每转动一小格的增(减)值
  51.         SDDS        EQU        027H        ;上电就自动设定的定时时间(小时)
  52.         SMGLD        EQU        028H          ;数码管亮度
  53.         DSSJS        EQU        029H        ;定时时间,时
  54.         DSSJF        EQU        02AH          ;定时时间,分
  55.         DSSJM        EQU        02BH        ;定时时间,秒
  56.         ZQ        EQU        02CH        ;T0中断使用,自然风通断电周期时长
  57.         SJ        EQU        02DH        ;T0中断使用,自然风时电机通电时长
  58.         SJJS        EQU        02EH          ;时间计数,每10毫秒减1,为0后定时时间减1秒,重新把HMJS处定义的计数值放入这里
  59.         MJS        EQU        02FH        ;按键处理时用,秒计数,每秒减1,直到为0
  60.         SSSC        EQU        030H        ;闪烁时长,每秒减1,直到为0
  61.         XSHC1        EQU        031H        ;上次显示的内容,与当前不同就立即显示,相同就每0.5秒显示一次
  62.         XSHC2        EQU        032H        ;上次显示的内容,与当前不同就立即显示,相同就每0.5秒显示一次
  63.         XXSZ        EQU        033H        ;下限数值,进行各项设置时用
  64.         SXSZ        EQU        034H        ;上限数值,进行各项设置时用
  65.         ZXM1        EQU        035H        ;显示用,待发送到TM1637的字形码1
  66.         ZXM2        EQU        036H        ;显示用,待发送到TM1637的字形码2
  67.         ZXM3        EQU        037H        ;显示用,待发送到TM1637的字形码3
  68.         ZXM4        EQU        038H        ;显示用,待发送到TM1637的字形码4
  69.         DSZJ        EQU        039H        ;加减定时时间使用
  70.         DISPL        EQU        03AH         ;设置要显示的目标:
  71.                                 ;0=显示定时时间
  72.                                 ;1=显示1——设置自然风状态时的通断电周期时长
  73.                                 ;2=显示2——设置自然风时电机通电时长
  74.                                 ;3=显示3——设置3小时以下定时调整时,编码器每转动一小格的增(减)值
  75.                                 ;4=显示4——设置上电自动填入的定时时间
  76.                                 ;5=显示5——设置数码管亮度

  77. ;--------------- 看门狗、EEPROM特殊功能寄存器地址 ---------------
  78.         AUXR                EQU 08EH        ;辅助寄存器
  79.         WDT_CONTR        EQU 0E1H        ;看门狗地址
  80.         IAP_DATA         EQU 0E2H        ;数据寄存器,读出、写入的数据放在此处
  81.         IAP_ADDRH        EQU 0E3H        ;地址寄存器高八位
  82.         IAP_ADDRL        EQU 0E4H        ;地址寄存器低八位
  83.         IAP_CMD                EQU 0E5H        ;命令寄存器,0=关闭,1=读,2=写,3=擦除
  84.         IAP_TRIG        EQU 0E6H        ;命令触发寄存器,每次操作先放入46H再放入B9,命令立即被触发起动
  85.         IAP_CONTR        EQU 0E7H        ;控制寄存器,Flash操作允许/禁止及等待时间
  86.         ENABLE_IAP        EQU 083H ;定义Flash操作等待时间及允许IAP/ISP/EEPROM操作的常数,时钟<12MHz时为83H

  87. ;===========================================================================================================
  88.         ORG        0000H
  89.         LJMP        START

  90.         ORG        0003H                ;外部中断INT0入口
  91.         LJMP        INT_0                ;外部中断INT0入口

  92.         ORG        000BH                ;T0中断入口
  93.         LJMP        T0INT                ;T0中断入口

  94.         ORG        0013H                ;外部中断INT1入口
  95.         LJMP        INT_1                ;外部中断INT1入口

  96.         ORG        0030H                ;程序代码始址安排在30H

  97. ;------------------------------------------------------------------------------------------------
  98. ;定义时间计数值,当定时时间实际走时误差较大时,可调整此数值使误差减小
  99. ;例如每分钟快7秒,就把此数值改为112D(7秒÷60秒×100≈12,12+100=112);每分钟慢6秒,就
  100. ;把此数值改为90D(6秒÷60秒×100=10,100-10=90)
  101. ;------------------------------------------------------------------------------------------------
  102. HMJS:        DB        100D                ;定义时间计数值,100表示100×10毫秒=1秒,后面的D表示是十进制数

  103. ;--------------- 定时器0中断(10毫秒产生一次中断) ---------------
  104. T0INT:        PUSH        ACC
  105.         PUSH        PSW
  106.         LCALL        TIME                ;处理各项时间
  107.         LCALL        Control                ;根据条件控制自然风LED指示灯和可控硅(或继电器)
  108.         LCALL        DISPLAY                ;显示
  109.         POP        PSW
  110.         POP        ACC
  111.         RETI

  112. ;--------------- 外部中断INT0,P3.2接编码器A引脚 ---------------
  113. INT_0:        PUSH        PSW
  114.         JB        00H,INT0_1        ;如果位地址0H为1就退出中断处理程序,等待主程序处理
  115.         SETB        00H                ;把位地址00H置为1,表示编码器已转动,等待主程序处理
  116.         SETB        01H                ;是顺时针正转,把位地址01H置为1
  117. INT0_1:        POP        PSW
  118.         RETI

  119. ;--------------- 外部中断INT1,P3.3接编码器B引脚 ---------------
  120. INT_1:        PUSH        PSW
  121.         JB        00H,INT1_1        ;如果位地址0H为1就退出中断处理程序,等待主程序处理
  122.         SETB        00H                ;把位地址00H置为1,表示编码器已转动,等待主程序处理
  123.         CLR        01H                ;是逆时针反转,把位地址01H置为0
  124. INT1_1:        POP        PSW
  125.         RETI

  126. ;--------------- 设置各项默认值 ----------------
  127. SZMRZ:        MOV        ZRFZQ,#10        ;自然风状态时,通断电周期时长(秒)
  128.         MOV        ZRFSJ,#5        ;自然风时电机通电时长(秒)
  129.         MOV        BMQZJ,#10          ;编码器每转动一小格的+、-值(分钟))
  130.         MOV        SDDS,#8                ;上电就自动设定的定时时间(小时)
  131.         MOV        SMGLD,#3          ;数码管亮度,8级亮度最高
  132.         RET

  133. ;--------------- T0、INT0、INT1中断设置 ----------------
  134. SETINT:        ANL        AUXR,#7FH        ;定时器时钟12T模式
  135.         ANL        TMOD,#0F0H        ;设置定时器模式
  136.         MOV        TL0,#000H        ;设置定时初值,10毫秒产生一次中断(晶振:11.0592MHz)
  137.         MOV        TH0,#0DCH        ;设置定时初值,10毫秒产生一次中断(晶振:11.0592MHz)
  138.         CLR        TF0                ;清除TF0标志
  139.         SETB        ET0                ;允许定时器0中断
  140.         SETB        TR0                ;定时器0开始计时
  141.         SETB        IT0                ;设外部中断INT0为下降沿触发
  142.         SETB        EX0                ;允许外部中断INT0
  143.         SETB        IT1                ;设外部中断INT1为下降沿触发
  144.         SETB        EX1                ;允许外部中断INT1
  145.         SETB        EA                ;允许全局中断
  146.         RET

  147. ;--------------- 启动看门狗及喂狗,11.0592MHz预分频数=4(142.2毫秒),00111001B(39H) ----------------
  148. WG:        MOV        WDT_CONTR,#00111001B
  149.         RET

  150. ;******************************************** 主程序开始 ********************************************
  151. START:        MOV        SP,#050H        ;设置堆栈指针
  152.         MOV        A,FWBZ1                ;
  153.         CJNE        A,#0C8H,START0        ;
  154.         MOV        A,FWBZ2                ;检查复位判断标志,不相同说明是初次上电,从初始化开始运行
  155.         CJNE        A,#0D9H,START0        ;
  156.         LCALL        SETINT                ;中断设置
  157.         CLR        RLED                ;RAM内容没变,说明是被干扰等原因复位,不是初次上电,点亮复位LED指示灯
  158.         MOV        A,DISPL                ;
  159.         CJNE        A,#5,SAT1        ;不管是什么原因复位,只要RAM不被改变就跳过初始化,继续运行
  160.         LJMP        STARTB                ;
  161. SAT1:        CJNE        A,#4,SAT2        ;
  162.         LJMP        STARTA                ;
  163. SAT2:        CJNE        A,#3,SAT3        ;根据DISPL的内容跳转到复位前的位置
  164.         LJMP        START9                ;
  165. SAT3:        CJNE        A,#2,SAT4        ;
  166.         LJMP        START8                ;
  167. SAT4:        CJNE        A,#1,START2        ;
  168.         LJMP        START7                ;
  169. START0:        CLR        A
  170.         MOV        R0,#30H                ;
  171.         MOV        R1,#20H                ;
  172. START1:        MOV        @R1,A                ;初始化,从RAM地址20H开始清零30H个字节
  173.         INC        R1                ;
  174.         DJNZ        R0,START1        ;
  175.         LCALL        SETINT                ;初始化,中断设置
  176.         MOV        FWBZ1,#0C8H        ;初始化,放入复位判断标志1到RAM
  177.         MOV        FWBZ2,#0D9H        ;初始化,放入复位判断标志2到RAM
  178.         LCALL        REEP                ;初始化,读EEPROM保存的各项设置,如果没有就设为默认值并保存
  179.         SETB        RLED                ;初始化,设RLED为高电平,复位LED指示灯不亮
  180. ;
  181. START2:        LCALL        WG                ;喂狗
  182.         MOV        DISPL,#0        ;设置要显示的目标,0=显示定时时间
  183.         CLR        06H                ;位地址06H置为0,显示定时时间
  184.         CLR        07H                ;位地址07H置为0,显示定时时间
  185.         JNB        00H,START3        ;如果位地址00H为0(编码器没有转动)就转移
  186.         SETB        EC11A                ;拉高编码器A引脚电平
  187.         SETB        EC11B                ;拉高编码器B引脚电平
  188.         JNB        EC11A,START3        ;如果仍为0(低电平)就转移,说明还没有旋转到卡点位置
  189.         JNB        EC11B,START3        ;如果仍为0(低电平)就转移,说明还没有旋转到卡点位置
  190.         LCALL        DSSJZJ                ;AB引脚都为高电平了,已经旋转到卡点位置,根据方向增减定时时间
  191.         CLR        00H                ;把位地址00H置为0,表示已经响应并处理编码器旋转动作
  192. START3:        LCALL        SKEY                ;扫描编码器按键开关
  193.         JNC        START2                ;没有按键动作(C=0)就转移
  194.         LCALL        KEY                ;有按键动作,调用编码器按键开关处理子程序
  195.         CJNE        A,#1,START4        ;如果不是按下1次(正常/自然风切换)就转移
  196.         CPL        02H                ;是按1次,位地址第02位取反,自然风/正常状态切换
  197.         LJMP        START2
  198. START4:        CJNE        A,#2,START5        ;如果不是2(定时时间置为零)就转移
  199.         LCALL        DSSJQL                ;是按2次,定时时间清零
  200.         LJMP        START2
  201. START5:        CJNE        A,#3,START7        ;如果不是3(恢复默认设置)就转移
  202.         LCALL        SZMRZ                ;恢复各项默认设置
  203.         SETB        06H                ;把位地址06H设置为1,数码管显示3秒88:88
  204.         MOV        SSSC,#3                ;3秒
  205.         MOV        ZXM1,#0FFH        ;8
  206.         MOV        ZXM2,#0FFH        ;8
  207.         MOV        ZXM3,#0FFH        ;8
  208.         MOV        ZXM4,#0FFH        ;8
  209.         LCALL        DISP                ;显示
  210. START6:        MOV        A,SSSC
  211.         LCALL        WG                ;喂狗
  212.         JNZ        START6                ;等待SSSC为0秒
  213.         LCALL        WSET                ;保存设置
  214.         LCALL        KEYEX                ;等待按键松开
  215.         LJMP        START2
  216. START7:        MOV        DISPL,#1        ;是4,进入各项设置,1=显示“1——设置自然风状态时通断电周期时长”
  217.         LCALL        ZQSZ                ;周期时长设置
  218.         JNZ        START8                ;如果是按下编码器按键开关返回,就转移,进行下一项设置
  219.         LJMP        START2                ;是15秒无操作自动保存返回,设置结束
  220. START8:        MOV        DISPL,#2        ;2=显示“2——设置自然风时电机通电时长”
  221.         LCALL        TDSC                ;通电时长设置
  222.         JNZ        START9                ;如果是按下编码器按键开关返回,就转移,进行下一项设置
  223.         LJMP        START2                ;是15秒无操作自动保存返回,设置结束
  224. START9:        MOV        DISPL,#3        ;3=显示“3——设置2小时以下定时调整时,编码器每转动一格的增(减)值”
  225.         LCALL        BMQZJZ                ;编码器增减值设置
  226.         JNZ        STARTA                ;如果是按下编码器按键开关返回,就转移,进行下一项设置
  227.         LJMP        START2                ;是15秒无操作自动保存返回,设置结束
  228. STARTA:        MOV        DISPL,#4        ;4=显示“4——设置插电自动填入的定时时间”
  229.         LCALL        SDDSSJ                ;上电定时时间设置(小时)
  230.         JNZ        STARTB                ;如果是按下编码器按键开关返回,就转移,进行下一项设置
  231.         LJMP        START2                ;是15秒无操作自动保存返回,设置结束
  232. STARTB:        MOV        DISPL,#5        ;5=显示“5——设置数码管亮度”
  233.         LCALL        LDSZ                ;亮度设置
  234.         LJMP        START2

  235. ;--------------------------------------------------------------------------------------------------------
  236. ;子程序:根据编码器旋转方向加减定时时间。
  237. ;3小时及以下,按设置的值加减:5、10、15、20、25、30分钟
  238. ;3小时以上每次增(减)30分钟;10小时以上每次增(减)1个小时;20小时以上每次增(减)2个小时
  239. ;--------------------------------------------------------------------------------------------------------
  240. DSSJZJ:        MOV        DSSJM,#59        ;先放入59到定时时间(秒)
  241.         MOV        A,DSSJS                ;装入定时时间(时)
  242.         CJNE        A,#20,DSZJ1        ;当前“时”是否等于或大于20
  243. DSZJ1:        JC        DSZJ2                ;小于就转移
  244.         MOV        DSZJ,#2                ;等于或大于20,加减2个小时
  245.         LJMP        DSZJ4
  246. DSZJ2:        CJNE        A,#10,DSZJ3        ;当前“时”是否等于或大于10
  247. DSZJ3:        JC        DSZJ8                ;小于就转移
  248.         MOV        DSZJ,#1                ;等于或大于10,加减1个小时
  249. DSZJ4:         JNB        01H,DSZJ6        ;如果位地址01H为0(逆时针反转)就转移
  250.         ADD        A,DSZJ                ;是正转,加
  251.         CJNE        A,#100,DSZJ5        ;加完后是否等于或大于100
  252. DSZJ5:        JC        DSZJ7                ;如果小于就转移,把A放回到DSSJS
  253.         MOV        DSSJS,#99        ;已经大于99了,直接设置为99:59:59
  254.         MOV        DSSJF,#59        ;已经大于99了,直接设置为99:59:59
  255.         RET
  256. DSZJ6:        SUBB        A,DSZJ                ;是反转,减
  257. DSZJ7:        MOV        DSSJS,A                ;把计算结果放入DSSJS
  258.         RET
  259. DSZJ8:        MOV        DSZJ,BMQZJ        ;把设置的“增(减)值”放入DSZJ
  260.         CJNE        A,#3,DSZJ11        ;当前“时”不是3就转移
  261.         JB        01H,DSZJ12         ;是3,如果位地址01H为1(正转)就转移,把DSZJ处的“增(减)值”改为30(分钟)
  262.         MOV        A,DSSJF                ;是反转,装入定时时间(分)
  263.         JZ        DSZJ13                ;如果当前“分”为0(3:00)就转移,按设置的增(减)值减
  264.         CJNE        A,#30,DSZJ9        ;“分”不为0,是否等于或大于30
  265. DSZJ9:        JC        DSZJ10                ;小于就转移,把0放入定时时间(分),使时间变为3:00
  266.         SUBB        A,#30                ;等于或大于,减30分
  267.         MOV        DSSJF,A                ;把计算结果放入定时时间(分)
  268.         RET
  269. DSZJ10:        MOV        DSSJF,#0        ;小于30,把0放入定时时间(分),使时间变为3:00
  270.         RET
  271. DSZJ11:        JC        DSZJ13                 ;小于3就转移
  272. DSZJ12:        MOV        DSZJ,#30        ;大于3:00,把DSZJ处的“增(减)值”改为30(分钟)
  273. DSZJ13:        MOV        A,DSSJF                ;装入定时时间(分)
  274.         JNB        01H,DSZJ16         ;如果位地址01H为0(逆时针反转)就转移
  275.         ADD        A,DSZJ                ;是正转,当前“分”直接加DSZJ处的“增(减)值”
  276.         CJNE        A,#60,DSZJ14        ;加完后“分”是否等于或大于60
  277. DSZJ14:        JC        DSZJ15                ;小于60就转移,把A放入定时时间(分)
  278.         SUBB        A,#60                ;等于或大于60,就减60,然后小时加1
  279.         MOV        DSSJF,A                ;把A放入定时时间(分)
  280.         MOV        A,DSSJS                ;装入“时”
  281.         INC        A                ;小时加1
  282.         MOV        DSSJS,A
  283.         CJNE        A,#3,DSZJ19        ;加完后“时”不是3就转移,退出
  284.         CLR        A                ;加完后大于3:00了,把0放入定时时间(分),使时间变为3:00
  285. DSZJ15:        MOV        DSSJF,A
  286.         RET
  287. DSZJ16:        CJNE        A,DSZJ,DSZJ17        ;是逆时针反转,当前“分”是否等于或大于DSZJ处的“增(减)值”
  288. DSZJ17:        JC        DSZJ20                ;小于就转移
  289.         SUBB        A,DSZJ                ;等于或大于,定时时间(分)减“增(减)值”
  290.         MOV        DSSJF,A                ;把计算结果放入定时时间(分)
  291.         JZ        DSZJ18                ;如果“分”为0就转移
  292.         RET
  293. DSZJ18:        CJNE        A,DSSJS,DSZJ19        ;如果“时”不为0就转移
  294.         MOV        DSSJM,A                ;“时、分”都为0,“秒”也清零
  295. DSZJ19:        RET
  296. DSZJ20:        MOV        A,DSZJ                ;“分”小于“增(减)值”,装入DSZJ处的“增(减)值”
  297.         CLR        C                ;进位标志清0
  298.         SUBB        A,DSSJF                ;“增(减)值”减“定时时间(分)”
  299.         MOV        DSSJF,A                ;减完后的结果暂时放入DSSJF
  300.         MOV        A,#60
  301.         SUBB        A,DSSJF                ;60减上面的计算结果,得出定时时间(分),然后小时减1
  302.         MOV        DSSJF,A                ;得出的数放入定时时间(分)
  303.         MOV        A,DSSJS                ;装入定时时间(时)
  304.         JZ        DSSJQL                ;如果“时”为0就转移(不够减了,把定时时间清零)
  305.         DEC        DSSJS                ;“时”不为0,减1
  306.         RET
  307. DSSJQL: CLR        A
  308.         MOV        DSSJS,A                ;定时时间清零
  309.         MOV        DSSJF,A                ;定时时间清零
  310.         MOV        DSSJM,A                ;定时时间清零
  311.         RET

  312. ;----------------------------------------------------------------------------------------
  313. ;设置自然风通断电周期时长,5~30秒
  314. ;----------------------------------------------------------------------------------------
  315. ZQSZ:        MOV        XXSZ,#5                ;下限为5秒
  316.         MOV        SXSZ,#30        ;上限为30秒
  317.         LJMP        LDSZ1

  318. ;----------------------------------------------------------------------------------------
  319. ;设置自然风时电机通电时长,最短为2秒;最长为上一项(自然风通断电周期)所设的周期减3秒
  320. ;----------------------------------------------------------------------------------------
  321. TDSC:        MOV        A,ZRFZQ                ;装入“自然风通断电周期”
  322.         SUBB        A,#3                ;减3秒
  323.         MOV        SXSZ,A                ;放入上限值
  324.         MOV        XXSZ,#2                ;下限为2秒
  325.         LJMP        LDSZ1

  326. ;----------------------------------------------------------------------------------------
  327. ;设置2小时以下定时调整时,编码器每转动一小格的增(减)值,5、10、15、20、25、30分钟
  328. ;----------------------------------------------------------------------------------------
  329. BMQZJZ:        MOV        XXSZ,#5                ;下限为5
  330.         MOV        SXSZ,#30        ;上限为30
  331.         MOV        R4,#5                ;调整时的加减步长值
  332.         LJMP        SZTZ

  333. ;----------------------------------------------------------------------------------------
  334. ;设置插电就自动填入的定时时间,0~30小时
  335. ;----------------------------------------------------------------------------------------
  336. SDDSSJ:        MOV        XXSZ,#0                ;下限为0小时
  337.         MOV        SXSZ,#30        ;上限为30小时
  338.         LJMP        LDSZ1

  339. ;----------------------------------------------------------------------------------------
  340. ;设置数码管亮度,1~8级,8级亮度最高
  341. ;----------------------------------------------------------------------------------------
  342. LDSZ:        MOV        XXSZ,#1                ;下限为1
  343.         MOV        SXSZ,#8                ;上限为8
  344. LDSZ1:        MOV        R4,#1                ;调整时的加减步长值
  345.         LJMP        SZTZ

  346. ;----------------------------------------------------------------------------------------
  347. ;子程序:根据XXSZ、SXSZ设定的上下限范围、编码器旋转方向,调整DISPL指向的对象。
  348. ;无操作10秒后开始闪烁显示,15秒自动保存并退出;有按键动作就保存并退出
  349. ;入口参数:下限值放入XXSZ;上限值放入SXSZ;R4=加、减步长值
  350. ;出口参数:15秒无操作自动保存退出A=0;按编码器按键开关保存退出A=1
  351. ;----------------------------------------------------------------------------------------
  352. SZTZ:        MOV        MJS,#15                ;放入15秒
  353.         CLR        03H                ;位地址03H置为0,允许检查剩余时间
  354. SZTZ1:        LCALL        SKEY                ;扫描编码器按键开关
  355.         JNC        SZTZ2                ;没有按键动作(C=0)就转移
  356.         CLR        04H                ;有按键动作,把位地址04H置为0,不闪烁显示
  357.         LCALL        WSET                ;保存设置
  358.         LCALL        KEYEX                ;等待按键松开
  359.         LCALL        SKEY1                ;延时10毫秒
  360.         LCALL        SKEY1                ;
  361.         LCALL        SKEY1                ;共延时30毫秒
  362.         MOV        A,#1                ;按编码器按键开关保存退出A=1
  363.         RET
  364. SZTZ2:        JB        00H,SZTZ4        ;如果位地址00H为1(编码器已经转动)就转移
  365.         MOV        A,MJS                ;没有转动,装入秒计数到寄存器A
  366.         JZ        SZTZ3                ;如果秒计数为0(15秒无操作)就转移
  367.         JB        03H,SZTZ1        ;不为0,如果位地址03H为1就转移,不检查剩余时间
  368.         CJNE        A,#5,SZTZ1        ;检查剩余时间,如果不是5秒就转移,继续扫描编码器
  369.         SETB        04H                ;还剩5秒,把位地址04H置为1,设置为闪烁显示
  370.         MOV        SSSC,A                ;闪烁时长5秒放入SSSC
  371.         SETB        03H                ;位地址03H置为1,禁止检查剩余时间
  372.         LJMP        SZTZ1
  373. SZTZ3:        CLR        04H                ;15秒时间到,把位地址04H置为0,不闪烁显示
  374.         LCALL        WSET                ;保存设置
  375.         CLR        A                ;15秒无操作自动保存退出A=0
  376.         RET
  377. SZTZ4:        CLR        04H                ;编码器已经转动,把位地址04H置为0,不闪烁显示
  378.         SETB        EC11A                ;拉高编码器A引脚电平
  379.         SETB        EC11B                ;拉高编码器B引脚电平
  380.         JNB        EC11A,SZTZ        ;如果仍为0(低电平)就转移,说明还没有旋转到卡点位置
  381.         JNB        EC11B,SZTZ        ;如果仍为0(低电平)就转移,说明还没有旋转到卡点位置
  382.         MOV        A,DISPL                ;AB引脚都为高电平,已经旋转到卡点位置了,装入要设置的目标项
  383.         DEC        A                ;减1
  384.         ADD        A,#ZRFZQ        ;加上各项设置的起始地址
  385.         MOV        R0,A                ;把得出的具体地址放入R0
  386.         JB        01H,SZTZ7         ;如果位地址01H为1(顺时针正转)就转移
  387.         MOV        A,XXSZ                ;是反转,装入下限数值到A寄存器
  388.         ADD        A,R4                ;加步长值
  389.         MOV        MJS,A                ;把下限值+步长值的结果暂时放入MJS
  390.         MOV        A,@R0                ;装入R0指向的RAM地址的调整对象数值
  391.         CJNE        A,MJS,SZTZ5        ;调整对象数值与“下限值+步长值”比较
  392. SZTZ5:        JC        SZTZ6                ;如果调整对象数值小于“下限值+步长值”(不够减)就转移
  393.         SUBB        A,R4                ;等于或大于,减步长值
  394.         MOV        @R0,A                ;把计算结果放回去
  395.         LJMP        SZTZ10
  396. SZTZ6:        MOV        @R0,XXSZ        ;不够减了,直接放入下限值
  397.         LJMP        SZTZ10
  398. SZTZ7:        MOV        A,@R0                ;是正转,装入R0指向的RAM地址的调整对象数值
  399.         ADD        A,R4                ;加步长值
  400.         CJNE        A,SXSZ,SZTZ8        ;加完后与上限数值比较
  401. SZTZ8:        JC        SZTZ9                ;如果小于就转移
  402.         MOV        @R0,SXSZ        ;等于或大于,直接放入上限值
  403.         LJMP        SZTZ10
  404. SZTZ9:        MOV        @R0,A                ;小于上限数值,把计算结果放回去
  405. SZTZ10:        CLR        00H                ;把位地址00H置为0,表示已经处理编码器旋转动作
  406.         LJMP        SZTZ

  407. ;----------------------------------------------------------------------------------------
  408. ;子程序:编码器按键开关处理
  409. ;出口参数:A=1(按了1次);A=2(按了2次);A=3长按达到了15秒;A=4长按达到了5秒
  410. ;----------------------------------------------------------------------------------------
  411. KEY:        MOV        MJS,#15                ;放入等待时间,15秒
  412. KEY1:        MOV        A,MJS                ;装入等待时间
  413.         JNZ        KEY2                ;如果不为0就转移,时间未到
  414.         MOV        A,#3                ;为0,时间到了,放入3到A寄存器,长按达到了15秒
  415.         RET
  416. KEY2:        LCALL        SKEY                ;扫描按键
  417.         JC        KEY1                ;如果C=1(按键还没松开),就继续扫描
  418.         CJNE        A,#10,KEY3        ;按键松开了,剩余时间与10比较,不等于就转移
  419.         LJMP        KEY4                ;等于10,长按时间达到了5秒(15-10=5)
  420. KEY3:        JNC        KEY5                ;大于10就转移
  421. KEY4:        MOV        A,#4                ;等于或小于10,放入4到A寄存器,长按时间达到了5秒以上
  422.         RET
  423. KEY5:        LCALL        KEYA                ;大于10,按下的时间小于5秒,扫描按键600毫秒
  424.         JZ        KEY6                ;如果600毫秒内有按键动作就转移
  425.         RET                        ;600毫秒内没有按键动作,这时A=1(按了1次),退出
  426. KEY6:        LCALL        KEYEX                ;等待第二次按键松开
  427.         MOV        A,#2                ;按键松开了,A=2(按了2次)
  428.         RET

  429. ;------------------ 扫描按键开关600毫秒,有按键动作A=0,无按键动作A=1 ------------------
  430. KEYA:        PUSH        03H
  431.         MOV        03H,#60                ;等待600毫秒,10*60=600毫秒
  432. KEYB:        MOV        A,SJJS                ;装入(10)毫秒计数
  433. KEYC:        CJNE        A,SJJS,KEYD        ;如果不相同就转移,说明时间已经过了10毫秒
  434.         LCALL        SKEY                ;扫描按键
  435.         JC        KEYE                ;如果有按键动作(C=1)就转移
  436.         LJMP        KEYC
  437. KEYD:        DJNZ        03H,KEYB        ;03H减1,不为0就转移,继续扫描
  438.         POP        03H
  439.         MOV        A,#1                ;600毫秒等待时间已到,A=1没有按键动作
  440.         RET
  441. KEYE:        POP        03H
  442.         CLR        A                ;600毫秒内有按键动作A=0
  443.         RET

  444. ;------------------ 等待按键松开 ------------------
  445. KEYEX:        LCALL        SKEY                ;扫描按键
  446.         JC        KEYEX                ;如果C=1(按键还没松开),就继续扫描
  447.         RET

  448. ;------------------ 按键开关扫描,未按C=0,已按下C=1 ------------------
  449. SKEY:        SETB        EC11K                ;按键开关设为高电平
  450.         JNB        EC11K,SKEY1        ;为0(低电平)就转移,表示按键开关已经被按下
  451. SKEY0:        CLR        C                ;为1(高电平),C置为0,没有按键动作
  452.         LCALL        WG                ;喂狗
  453.         RET
  454. SKEY1:        PUSH        00H                ;按键已被按下,延时10毫秒
  455.         PUSH        01H                ;延时10毫秒
  456.         MOV        00H,#87                ;延时10毫秒
  457.         MOV        01H,#10                ;延时10毫秒
  458. SKEY2:        DJNZ        01H,SKEY2        ;延时10毫秒
  459.         DJNZ        00H,SKEY2        ;延时10毫秒
  460.         POP        01H                ;延时10毫秒
  461.         POP        00H                ;延时10毫秒
  462.         SETB        EC11K                ;延时结束后再次把按键开关设为高电平
  463.         JB        EC11K,SKEY0        ;为1就转移,按键开关未被有效按下
  464.         SETB        C                ;为1,按键动作有效,置C为1
  465.         LCALL        WG                ;喂狗
  466.         RET

  467. ;*************************** 以下为EEPROM操作子程序 **********************************
  468. ;STC89C51RC有4K字节的EEPROM,由8个扇区组成,每个扇区512字节,地址2000H-2FFFH
  469. ;第1扇区:2000H~21FFH,第2扇区:2200H~23FFH……第8扇区:2E00H~2FFFH
  470. ;-------------------------------------------
  471. ;读一字节,A=读出的数据
  472. Byte_Read:
  473.         MOV        IAP_CONTR,#ENABLE_IAP        ;打开IAP功能,设置Flash操作等待时间(83H)
  474.         MOV        IAP_CMD,#01                ;设置为IAP/ISP/EEPROM字节读模式命令(1)
  475.         MOV        IAP_TRIG,#46H                ;先送46H
  476.         MOV        IAP_TRIG,#0B9H                ;再送B9H,ISP/IAP命令立即被触发起动
  477.         NOP
  478.         MOV        A,IAP_DATA                ;读出的数据在IAP_DATA单元中,送入累加器A
  479.         RET
  480. ;-------------------------------------------
  481. ;字节编程,A=需写入的数据
  482. Byte_Program:
  483.         MOV        IAP_CONTR,#ENABLE_IAP        ;打开IAP功能,设置Flash操作等待时间(83H)
  484.         MOV        IAP_CMD,#02                ;设置为IAP/ISP/EEPROM字节编程模式命令(2)
  485.         MOV        IAP_DATA,A                ;要编程的数据先送进IAP_DATA寄存器
  486.         MOV        IAP_TRIG,#46H                ;先送46H
  487.         MOV        IAP_TRIG,#0B9H                ;再送B9H,ISP/IAP命令立即被触发起动
  488.         RET
  489. ;-------------------------------------------
  490. ;擦除扇区
  491. Sector_Erase:
  492.         MOV        IAP_CONTR,#ENABLE_IAP        ;打开IAP功能,设置Flash操作等待时间(83H)
  493.         MOV        IAP_CMD,#03                ;设置为IAP/ISP/EEPROM扇区擦除模式命令(3)
  494.         MOV        IAP_TRIG,#46H                ;先送46H
  495.         MOV        IAP_TRIG,#0B9H                ;再送B9H,ISP/IAP命令立即被触发起动
  496.         NOP
  497.         RET

  498. ;---------- 读EEPROM保存的各项设置,如果没有就设置为默认值并保存 ------------
  499. REEP:        LCALL        RE00                ;读EEPROM保存的各项设置
  500.         MOV        A,SDDS                ;装入“上电就自动设定的定时时间(小时)”
  501.         JZ        REEP0                ;如果是0就转移,退出
  502.         MOV        DSSJS,A                ;放入“定时时间(小时)”
  503.         MOV        DSSJM,#59        ;放入59到“定时时间(秒)”
  504. REEP0:        RET
  505. RE00:        MOV        IAP_ADDRH,#020H        ;从第一个扇区开始搜索,地址的高8位
  506. RE01:        MOV        IAP_ADDRL,#0        ;从第一个扇区开始搜索,地址的低8位
  507.         LCALL        Byte_Read        ;读第一个字节,返回:A=读出的数据
  508.         CJNE        A,FWBZ1,RE03        ;是否保存在当前扇区,不是就转移到RE03
  509.         INC        IAP_ADDRL        ;EEPROM字节地址增1
  510.         LCALL        Byte_Read        ;读第二个字节
  511.         CJNE        A,FWBZ2,RE03        ;第二个字节是否相符
  512.         MOV        R1,#ZRFZQ        ;相符,从ZRFZQ开始放置读出的设置值
  513.         MOV        R2,#5                ;总共5个字节
  514. RE02:        INC        IAP_ADDRL        ;EEPROM字节地址增1
  515.         LCALL        Byte_Read        ;读一个字节,返回:A=读出的数据
  516.         MOV        @R1,A                ;放到R1指向的RAM地址
  517.         INC        R1                ;RAM地址增1
  518.         DJNZ        R2,RE02                ;未读完就继续
  519.         RET                        ;读完了,退出
  520. RE03:        MOV        A,IAP_ADDRH        ;装入扇区地址的高8位
  521.         ADD        A,#2                ;扇区增1
  522.         MOV        IAP_ADDRH,A        ;放入IAP_ADDRH
  523.         CJNE        A,#30H,RE01        ;如果未搜索完最后一个扇区+2(2EH+2=30H)就转移,继续搜索
  524.         LCALL        SZMRZ                ;已经搜索全部八个扇区,未找到保存的内容,设置为默认值
  525.         MOV        R0,#8                ;总扇区数量,共8个扇区
  526.         LJMP        WSET3                ;跳转到WSET3保存设置

  527. ;------------------ 保存设置,不固定保存到某个扇区,各扇区轮流使用 ------------------
  528. WSET:        MOV        R0,#8                ;扇区总数量,共8个扇区
  529.         MOV        IAP_ADDRH,#020H        ;从第一个扇区开始搜索上次保存的设置
  530. WSET1:        MOV        IAP_ADDRL,#0        ;地址低位指向第一个字节
  531.         LCALL        Byte_Read        ;读第一个字节,返回:A=读出的数据
  532.         CJNE        A,FWBZ1,WSET7        ;如果与EEPROM数据判断标志1不相同就转移
  533.         INC        IAP_ADDRL        ;第一个字节相同,EEPROM字节地址增1
  534.         LCALL        Byte_Read        ;读第二个字节
  535.         CJNE        A,FWBZ2,WSET7        ;如果与EEPROM数据判断标志2不相同就转移
  536.         MOV        IAP_ADDRL,#0        ;是在当前扇区,地址指向扇区第一个字节
  537.         LCALL        Sector_Erase        ;擦除当前扇区,另换一个扇区保存
  538. WSET2:        MOV        A,IAP_ADDRH        ;装入扇区地址高位到寄存器A
  539.         CJNE        A,#020H,WSET3        ;当前扇区地址高位如果不是20H(第一个扇区)就转移
  540.         MOV        IAP_ADDRH,#30H        ;是20H,把IAP_ADDRH设置为最后一个扇区+2(2EH+2=30H)
  541. WSET3:        DEC        IAP_ADDRH        ;减1
  542.         DEC        IAP_ADDRH        ;再减1,指向上一个扇区首址
  543.         MOV        IAP_ADDRL,#0        ;低8位指向扇区第一个字节
  544.         LCALL        Sector_Erase        ;擦除整个扇区
  545.         MOV        R1,#FWBZ1        ;要保存的内容始址
  546.         MOV        R2,#7                ;共7个字节
  547. WSET4:        MOV        A,@R1                ;装入R1指向的RAM地址的内容到A
  548.         LCALL        Byte_Program        ;字节编程(写入EEPROM)
  549.         INC        IAP_ADDRL        ;EEPROM地址加1
  550.         INC        R1                ;RAM地址增1
  551.         DJNZ        R2,WSET4        ;未保存完就继续
  552.         MOV        IAP_ADDRL,#0        ;保存完了,扇区地址低位指向0(当前扇区首址)
  553.         LCALL        Byte_Read        ;读出来检查看是否写入成功
  554.         CJNE        A,FWBZ1,WSET5        ;如果与EEPROM数据判断标志1不相同就转移
  555.         INC        IAP_ADDRL        ;EEPROM地址加1
  556.         LCALL        Byte_Read        ;读第二个字节
  557.         CJNE        A,FWBZ2,WSET5        ;如果与EEPROM数据判断标志2不相同就转移
  558.         RET                        ;成功了,退出
  559. WSET5:        DJNZ        R0,WSET2        ;如果未试完8个扇区就转移到WSET2继续往前一个扇区写
  560.         SETB        07H                ;已经试完8个扇区,都失败了,位地址07H置为1
  561.         MOV        SSSC,#5                ;显示E1五秒
  562.         MOV        ZXM1,#0                ;消隐码
  563.         MOV        ZXM2,#079H        ;E
  564.         MOV        ZXM3,#006H        ;1
  565.         MOV        ZXM4,#0                ;消隐码
  566.         LCALL        DISP                ;显示
  567. WSET6:        MOV        A,SSSC
  568.         LCALL        WG                ;喂狗
  569.         JNZ        WSET6                ;等待SSSC为0秒
  570.         CLR        07H                ;显示结束,位地址07H置为0
  571.         RET
  572. WSET7:        MOV        A,IAP_ADDRH        ;装入扇区地址高位
  573.         ADD        A,#2                ;加2,指向下一个扇区首址
  574.         MOV        IAP_ADDRH,A        ;放回IAP_ADDRH
  575.         CJNE        A,#30H,WSET1        ;如果未到最后一个扇区地址高位+2(2EH+2=30H)就转移到WSET1继续搜索
  576.         LJMP        WSET3                ;是30H,已经搜索完所有扇区,未找到上次保存的数据,跳转到WSET3保存当前设置
  577. ;***************************************** 以上为EEPROM操作子程序 ********************************************

  578. ;------------------------------------------------------------------------------------------
  579. ;子程序:T0中断调用,时间计数及倒计时处理
  580. ;------------------------------------------------------------------------------------------
  581. TIME:        MOV        A,SJJS                 ;装入(10)毫秒时间计数
  582.         JZ        TIME2                ;如果是0就转移
  583.         DEC        SJJS                ;不是0,减1
  584.         CJNE        A,#50,TIME1        ;如果不是50就转移退出
  585.         CPL        05H                ;位地址第05位取反,数字及冒号闪烁时用,每0.5秒取反一次
  586. TIME1:        RET
  587. TIME2:        CPL        05H                ;是0,位地址第05位取反,数字及冒号闪烁时用,每0.5秒取反一次
  588.         MOV        DPTR,#HMJS        ;把定义的时间计数值地址装入数据指针DPTR
  589.         MOVC        A,@A+DPTR        ;从程序存储区装入时间计数值到A寄存器
  590.         MOV        SJJS,A                ;时间计数值放入SJJS,重新计数
  591.         MOV        A,MJS                 ;装入秒计数
  592.         JZ        TIME20                ;如果是0就转移
  593.         DEC        MJS                ;不是0,减1秒
  594. TIME20:        MOV        A,SSSC                 ;装入闪烁时长秒计数
  595.         JZ        TIME3                ;如果是0就转移
  596.         DEC        SSSC                ;不是0,减1秒
  597. TIME3:        MOV        A,SJ                ;装入自然风时电机通电时长到寄存器A
  598.         JZ        TIME4                ;如果是0就转移
  599.         DEC        SJ                ;不是0,减1秒
  600. TIME4:        MOV        A,ZQ                ;装入自然风变化周期时长到寄存器A
  601.         DEC        ZQ                ;先减1
  602.         JNZ        TIME5                ;如果不是0就转移
  603.         MOV        ZQ,ZRFZQ        ;是0,重新装入设置值
  604.         MOV        SJ,ZRFSJ        ;是0,重新装入设置值
  605. TIME5:        MOV        A,DSSJM                ;装入定时时间(秒)到寄存器A
  606.         JZ        TIME7                ;如果是0就转移
  607.         CJNE        A,#59,TIME6        ;如果不是59秒就转移
  608.         MOV        A,DSSJF                ;是59秒,检查“时”
  609.         JNZ        TIME6                ;不是0就转移
  610.         MOV        A,DSSJS                ;检查“分”
  611.         JNZ        TIME6                ;不是0就转移
  612.         MOV        DSSJM,A                ;“时、分”都是0,把“秒”也清零
  613.         RET
  614. TIME6:        DEC        DSSJM                ;不是0,减1秒
  615.         RET
  616. TIME7:        MOV        A,DSSJF                ;装入定时时间(分)到寄存器A
  617.         JZ        TIME8                ;如果是0就转移
  618.         DEC        DSSJF                ;不是0,减1分
  619.         MOV        DSSJM,#59        ;把59放入定时时间(秒)
  620.         RET
  621. TIME8:        MOV        A,DSSJS                ;装入定时时间(时)到寄存器A
  622.         JZ        TIME9                ;如果是0就转移,退出
  623.         DEC        DSSJS                ;不是0,小时减1
  624.         MOV        DSSJM,#59        ;把59放入定时时间(秒)
  625.         MOV        DSSJF,#59        ;把59放入定时时间(分)
  626. TIME9:        RET

  627. ;---------------------------------------------------------------------------------------------
  628. ;子程序:T0中断调用,根据条件控制自然风状态LED指示灯和可控硅(或继电器)
  629. ;---------------------------------------------------------------------------------------------
  630. Control:SETB        LED                ;先熄灭自然风LED指示灯
  631.         JNB        02H,CTL00        ;如果位地址02H(正常/自然风切换)为0(正常)就转移,保持熄灭状态
  632.         CLR        LED                ;为1,自然风状态,点亮LED指示灯
  633. CTL00:        MOV        A,DSSJM                ;装入定时时间(秒)到寄存器A
  634.         JNZ        CTL02                ;如果不是0就转移
  635.         MOV        A,DSSJF                ;装入定时时间(分)到寄存器A
  636.         JNZ        CTL02                ;如果不是0就转移
  637.         MOV        A,DSSJS                ;装入定时时间(时)到寄存器A
  638.         JNZ        CTL02                ;如果不是0就转移
  639. CTL01:        SETB        MOC                ;置MOC为高电平,断电
  640.         RET
  641. CTL02:        JNB        02H,CTL03        ;如果位地址02H(正常/自然风切换)为0(正常)就转移,通电
  642.         MOV        A,SJ                ;是自然风状态,装入自然风时电机通电时长到寄存器A
  643.         JZ        CTL01                ;如果为0(通电倒计时结束)就转移,断电
  644. CTL03:        CLR        MOC                ;置MOC为低电平,通电
  645.         RET

  646. ;------------------------------------------------------------------------------------------
  647. ;子程序:T0中断调用,显示定时时间及各项设置的内容
  648. ;------------------------------------------------------------------------------------------
  649. DISPLAY:JB        06H,DPYSZ1        ;如果位地址06H为1就转移退出,主程序显示88:88
  650.         JB        07H,DPYSZ1        ;如果位地址07H为1就转移退出,主程序显示E1
  651.         MOV        A,DISPL                ;装入要显示的目标
  652.         JZ        DISPL0                ;如果是0(显示定时时间)就转移
  653. DPYSZ:        PUSH        ACC
  654.         MOV        DPTR,#SEGTAB        ;查表获取字形码
  655.         MOVC        A,@A+DPTR        ;查表获取字形码
  656.         MOV        ZXM1,A                ;项目编号字形码放到待发送TM1637区1
  657.         MOV        ZXM2,#40H        ;放入“-”的字形码到待发送TM1637区2
  658.         POP        ACC
  659.         DEC        A                ;减1
  660.         PUSH        01H
  661.         MOV        R1,#ZRFZQ        ;各项设置值始址
  662.         ADD        A,R1                ;加上项目号
  663.         MOV        R1,A                ;得出设置项目的实际地址放入R1
  664.         MOV        A,@R1                ;装入设置值
  665.         POP        01H
  666.         MOV        B,A                ;放入B寄存器
  667.         CJNE        A,XSHC1,DPYSZ3        ;当前设置值与显示缓存1不相同就转移,立即显示
  668.         MOV        A,SJJS                 ;相同,装入时间计数
  669.         JNZ        DPYSZ2                ;不是0就转移,每半秒(遇到50或0)显示一次
  670.         LJMP        DPYSZ3                ;是0,显示
  671. DPYSZ1:        RET
  672. DPYSZ2:        CJNE        A,#50,DPYSZ1        ;不是50就转移退出,每半秒(遇到50或0)显示一次
  673. DPYSZ3:        MOV        XSHC1,B                ;当前设置值放入显示缓存1
  674.         JNB        04H,DPYSZ4        ;如果位地址04H为0(不闪烁)就转移
  675.         JNB        05H,DPYSZ4        ;为1,闪烁显示,如果位地址05H为0(显示)就转移
  676.         CLR        A                ;为1,处于闪烁显示中的“不显示”状态,放入消隐码
  677.         MOV        ZXM1,A                ;放入消隐码
  678.         MOV        ZXM2,A                ;放入消隐码
  679.         MOV        ZXM3,A                ;放入消隐码
  680.         MOV        ZXM4,A                ;放入消隐码
  681.         LJMP        disp                ;跳转到disp,发送4个字节数据到TM1637显示
  682. DPYSZ4:        MOV        A,B                ;当前设置值放入A寄存器
  683.         LCALL        DISPL6                ;转换并获取字形码放到待发送TM1637区3和4
  684.         LJMP        disp                ;跳转到disp,发送4个字节数据到TM1637显示
  685. DISPL0:        MOV        A,DSSJS                ;显示定时时间,装入定时时间(时)
  686.         CJNE        A,XSHC1,DISPL3        ;定时时间(时)与显示缓存1不相同就转移,显示
  687.         MOV        A,DSSJF
  688.         CJNE        A,XSHC2,DISPL3        ;定时时间(分)与显示缓存2不相同就转移,显示
  689.         MOV        A,SJJS                 ;时、分都相同,装入(10)毫秒时间计数
  690.         JNZ        DISPL2                ;不是0就转移
  691.         LJMP        DISPL3                ;是0,显示,每半秒(遇到50或0)显示一次
  692. DISPL1:        RET
  693. DISPL2:        CJNE        A,#50,DISPL1        ;不是50就转移,每半秒(遇到50或0)显示一次
  694. DISPL3:        MOV        XSHC1,DSSJS        ;当前时间放入显示缓存1
  695.         MOV        XSHC2,DSSJF        ;当前时间放入显示缓存2
  696.         MOV        A,DSSJM                ;
  697.         JNZ        DISPL4                ;检查当前定时时间是否全部为0,不是就转移
  698.         MOV        A,DSSJF                ;
  699.         JNZ        DISPL4                ;检查当前定时时间是否全部为0,不是就转移
  700.         MOV        A,DSSJS                ;
  701.         JNZ        DISPL4                ;检查当前定时时间是否全部为0,不是就转移
  702.         CLR        05H                ;定时时间为0,把位地址05H置为0,冒号不闪烁显示
  703. DISPL4:        MOV        A,DSSJS                ;装入“时”
  704.         MOV        B,#10                ;转换为BCD码
  705.         DIV        AB                ;转换为BCD码
  706.         MOV        DPTR,#SEGTAB        ;查表获取字形码
  707.         MOVC        A,@A+DPTR        ;查表获取字形码
  708.         MOV        ZXM1,A                ;字形码放入待发送TM1637区1
  709.         XCH        A,B                ;A、B寄存器内容交换
  710.         MOVC        A,@A+DPTR        ;查表获取字形码
  711.         JB        05H,DISPL5        ;如果05H为1就转移,不显示冒号
  712.         ORL        A,#10000000B        ;为0,把最高位置为1,显示冒号(字形码的最高位为1就显示冒号)
  713. DISPL5:        MOV        ZXM2,A                ;放入待发送TM1637区2
  714.         MOV        A,DSSJF                ;装入“分”
  715.         LCALL        DISPL6                ;转换并获取字形码放到待发送TM1637区3和4
  716.         LJMP        disp                ;跳转到disp,发送4个字节数据到TM1637显示
  717. DISPL6:        MOV        B,#10                ;转换为BCD码
  718.         DIV        AB                ;转换为BCD码
  719.         MOV        DPTR,#SEGTAB        ;查表获取字形码
  720.         MOVC        A,@A+DPTR        ;查表获取字形码
  721.         MOV        ZXM3,A                ;字形码放入待发送TM1637区3
  722.         XCH        A,B                ;A、B寄存器内容交换
  723.         MOVC        A,@A+DPTR        ;查表获取字形码
  724.         MOV        ZXM4,A                ;字形码放入待发送TM1637区4
  725.         RET

  726. ;------------------ 发送4个字节数据到TM1637显示,地址自动加1 ------------------
  727. disp:        LCALL        Srt
  728.         MOV          A,#040H                ;数据命令设置40H:地址自动加1,写数据到显示寄存器
  729.         LCALL        Writebyte        ;发送一个字节
  730.         LCALL        Stop
  731.         NOP
  732.         LCALL        Srt
  733.         MOV          A,#0C0H                ;地址命令设置C0H:初始地址为00H
  734.         LCALL        Writebyte        ;发送一个字节
  735.         PUSH        01H
  736.         PUSH        06H
  737.         MOV        06H,#4                ;发送4个字节数据
  738.         MOV          R1,#ZXM1        ;等待发送的字形码始址
  739. disp1:        MOV          A,@R1                ;装入要发送的字形码
  740.         LCALL        Writebyte        ;发送一个字节
  741.         INC          R1                ;地址加1
  742.         DJNZ        06H,disp1            ;如果还未发送完就继续
  743.         POP        06H
  744.         POP        01H
  745.         LCALL        Stop
  746.         LCALL        Srt
  747.         MOV        A,SMGLD                ;装入设置的数码管亮度(1~8)
  748.         ADD        A,#087H                ;加上87H后即为对应的亮度控制命令88H~8FH
  749.         LCALL        Writebyte        ;按设置的亮度开显示
  750.         LJMP         Stop

  751. ;------------------ 发送8bit(一个字节)数据到TM1637,A=要发送的数据,从低位开始 ------------------
  752. Writebyte:
  753.         PUSH        00H
  754.         MOV        00H,#8                ;发送8位数据
  755. WBY1:        CLR          CLK                ;拉低CLK
  756.         JNB          ACC.0,WBY2        ;A寄存器的低位(0位)如果为0就转移
  757.         SETB         DIO                ;为1,拉高DIO
  758.         SJMP         WBY3
  759. WBY2:        CLR          DIO                ;为0,拉低DIO
  760. WBY3:        NOP         
  761.         NOP         
  762.         NOP         
  763.         NOP         
  764.         NOP         
  765.         SETB         CLK                ;拉高CLK
  766.         CLR          C                ;进位标志清0
  767.         RRC          A                ;A寄存器内容带进位循环右移
  768.         DJNZ        00H,WBY1            ;如果还未发送完8bit数据就继续
  769. WBY4:        CLR          CLK                ;8位数据发送完了
  770.         NOP
  771.         MOV        00H,#05                ;设置等待应答信号计数值,防止万一与TM1637通讯失败而造成死循环
  772. WBY5:        DEC        00H                ;减1,正常情况下ACK应答信号很快,第一次减1就会有应答
  773.         MOV        A,00H                ;装入计数值到A
  774.         JZ        WBY6                ;如果为0就转移退出,说明与TM1637通讯失败,或TM1637不存在
  775.         JB        DIO,WBY5        ;不为0,判断TM1637发过来的ACK应答信号,未应答(为1,高电平)就转移
  776. WBY6:        POP        00H
  777.         NOP         
  778.         NOP         
  779.         NOP
  780.         SETB         CLK
  781.         NOP         
  782.         NOP         
  783.         NOP
  784.         RET         

  785. ;------------------ Start子程序 ------------------
  786. Srt:        SETB         DIO        ;拉高DIO
  787.         SETB         CLK        ;拉高CLK
  788.         NOP         
  789.         NOP         
  790.         NOP         
  791.         NOP         
  792.         NOP         
  793.         SETB         DIO        ;拉高DIO
  794.         NOP         
  795.         NOP         
  796.         NOP         
  797.         NOP         
  798.         NOP         
  799.         CLR          DIO        ;拉低DIO
  800.         NOP         
  801.         NOP         
  802.         NOP         
  803.         NOP         
  804.         NOP         
  805.         CLR          CLK        ;拉低CLK
  806.         RET         

  807. ;------------------ Stop子程序 ------------------
  808. Stop:        CLR          CLK
  809.         NOP         
  810.         NOP         
  811.         NOP         
  812.         NOP         
  813.         NOP         
  814.         NOP         
  815.         NOP         
  816.         NOP         
  817.         NOP         
  818.         NOP         
  819.         CLR          DIO
  820.         NOP         
  821.         NOP         
  822.         NOP         
  823.         NOP         
  824.         NOP         
  825.         NOP         
  826.         NOP         
  827.         NOP         
  828.         NOP         
  829.         NOP         
  830.         SETB         CLK
  831.         NOP         
  832.         NOP         
  833.         NOP         
  834.         NOP         
  835.         NOP         
  836.         NOP         
  837.         NOP         
  838.         NOP         
  839.         NOP         
  840.         NOP         
  841.         NOP         
  842.         NOP         
  843.         NOP         
  844.         NOP         
  845.         NOP         
  846.         SETB         DIO
  847.         NOP         
  848.         NOP         
  849.         NOP         
  850.         NOP         
  851.         NOP         
  852.         CLR          CLK
  853.         CLR          DIO
  854.         RET         

  855. ;------------------ 字形表 ------------------
  856. SEGTAB:
  857.         DB  00111111B  ;0(3FH)
  858.         DB  00000110B  ;1(06H)
  859.         DB  01011011B  ;2(5BH)
  860.         DB  01001111B  ;3(4FH)
  861.         DB  01100110B  ;4(66H)
  862.         DB  01101101B  ;5(6DH)
  863.         DB  01111101B  ;6(7DH)
  864.         DB  00000111B  ;7(07H)
  865.         DB  01111111B  ;8(7FH)
  866.         DB  01101111B  ;9(6FH)
  867.         DB  01110111B  ;A(77H)
  868.         DB  01111100B  ;B(7CH)
  869.         DB  00111001B  ;C(39H)
  870.         DB  01011110B  ;D(5EH)
  871.         DB  01111001B  ;E(79H)
  872.         DB  01110001B  ;F(71H)
  873.         DB  00000000B  ;消隐码(00)

  874. ;------------------------------------------------------------------------------------------

  875. END
复制代码



电风扇长定时器.rar (95.52 KB, 下载次数: 15)



STC89C51RC+TM1637显示模块+EC11编码器,电风扇长定时+自然风升级版
https://www.mydigit.cn/forum.php?mod=viewthread&tid=179460

打赏

参与人数 4家元 +128 收起 理由
guangqu + 8
家睦 + 100 原創內容
hxjxyz + 12 膜拜大佬
xiaoqi233 + 8

查看全部打赏

发表于 2020-7-11 01:53:03 | 显示全部楼层
楼主 凌晨发帖辛苦了!
回复 支持 反对

使用道具 举报

发表于 2020-7-11 08:07:24 | 显示全部楼层
楼主确实是无私奉献啊
回复 支持 反对

使用道具 举报

发表于 2020-7-11 09:29:24 | 显示全部楼层
看见汇编码的程序,不禁感叹是个大神!
回复 支持 反对

使用道具 举报

发表于 2020-7-11 11:30:01 | 显示全部楼层
没仔细看代码,不过光看线路,文字说明和注释,就觉得这是个比较成熟的作品,更牛B之处在于竟然是汇编写的,老鸟!高手!膜拜~
回复 支持 反对

使用道具 举报

发表于 2020-7-11 13:56:32 | 显示全部楼层
汇编厉害了:praise:。
回复 支持 反对

使用道具 举报

发表于 2020-7-11 14:40:03 来自手机浏览器 | 显示全部楼层
汇编…腻害了…
回复 支持 反对

使用道具 举报

发表于 2020-7-11 19:52:00 | 显示全部楼层
汇编厉害了:handshake::praise::praise:
回复 支持 反对

使用道具 举报

发表于 2020-7-12 01:14:05 | 显示全部楼层
看见汇编格外亲~~~~~~
回复 支持 反对

使用道具 举报

发表于 2020-7-12 09:53:37 | 显示全部楼层
本帖最后由 la45088d1 于 2020-7-12 09:54 编辑

其实ASM最好多文件分模块写,尽量做到结构化像高级语言一样。看了好多别人写的ASM工程,一个文件里面一大段指令,由很多分支组成,然后程序一开始就是一连串数不清的判断然后跳转到后面的一连串分支的其中一个,然后某个分支结束以后吧,又跳到另一个分支里去,来回横跳,这就是ASM人家觉得难得原因吧?
看过一本书,作者表示即使ASM程序也最好不要放弃结构化编程的风格,把每个功能分模块,模块的层次联系写清楚,C\C++怎么做,ASM也怎么做,否则搞出像上述的“意大利面式”的ASM程序,跳来跳去,逻辑结构难以琢磨,会给后续维护升级带来极大的困难。

意大利面条代码:代码过度使用GOTO语句而不是结构化编程结构,从而导致错综复杂和不可维护的程序,通常称为意大利面条代码。 这样的代码有一个复杂和纠结的控制结构,导致程序流程在概念上就像一碗意大利面,扭曲和纠结。在美国国家标准局1980年出版的一本出版物中,用“意大利面条”这个词来描述那些“分散和分散的文件”的较旧的节目。 意大利面代码也可以描述一种反向模式,在这种模式下,面向对象是以程序风格编写的,比如创建方法过于冗长和混乱的类,或者抛弃面向对象的概念,比如多态。这种形式的意大利面代码的存在可能会显着降低系统的可理解性

打赏

参与人数 1家元 +10 收起 理由
家睦 + 10

查看全部打赏

回复 支持 1 反对 0

使用道具 举报

发表于 2020-7-12 14:49:01 | 显示全部楼层
汇编大佬有意思
不过给个简易 几十个小时的定时 最好用RTC 那个主晶振不准的
回复 支持 反对

使用道具 举报

发表于 2020-7-12 20:40:44 | 显示全部楼层
牛啊。。汇编。。。
我现在寄存器都不想去了解了。:dizzy:
回复 支持 反对

使用道具 举报

发表于 2020-7-13 11:54:57 | 显示全部楼层
我是搬运工,方便大家系统学习:数码管+EC11编码器旋钮,定时器模式,100%正确率
http://bbs.mydigit.cn/read.php?tid=2602101
回复 支持 反对

使用道具 举报

发表于 2020-7-14 16:10:38 | 显示全部楼层
佩服,看不懂哦
回复 支持 反对

使用道具 举报

发表于 2020-7-16 18:13:15 | 显示全部楼层
我是解决办法是买了个傻瓜式的定时插座,按一下就好:lol:

一个接电蚊香、一个插电动车充电器、一个控制风扇。完美。

[url]https://www.mydigit.cn/forum.php?mod=viewthread&tid=172815&extra=

[/url]
https://www.mydigit.cn/forum.php?mod=viewthread&tid=166510&extra=


回复 支持 反对

使用道具 举报

发表于 2020-7-17 14:12:54 | 显示全部楼层
教科书级的汇编代码,厉害!
回复 支持 反对

使用道具 举报

发表于 2020-7-17 17:01:03 | 显示全部楼层
卧槽,汇编。大佬
回复 支持 反对

使用道具 举报

发表于 2020-7-19 23:00:22 | 显示全部楼层
会写程序的大佬才是真正的大佬 膜拜下:lol:
回复 支持 反对

使用道具 举报

发表于 2020-7-21 03:52:37 | 显示全部楼层
厉害,要是我肯定要C写了,这种代码用不着用汇编,杀鸡用牛刀了,不过楼主是高手
回复 支持 反对

使用道具 举报

您需要登录后才可以回帖 登录 | 立即注册

本版积分规则

APP|手机版|小黑屋|关于我们|联系我们|法律条款|技术知识分享平台

闽公网安备35020502000485号

闽ICP备2021002735号-2

GMT+8, 2024-3-29 22:27 , Processed in 0.124800 second(s), 11 queries , Redis On.

Powered by Discuz!

© 2006-2023 smzj.net

快速回复 返回顶部 返回列表