ESP8266播放MP3

mckk520 · 发表于 2020-5-4 08:08:12

，
，
，
，
======================

// 按钮控制播放音频
//#include <ESP8266WiFi.h>
#include <Arduino.h>
#include "AudioFileSourceSPIFFS.h"
#include "AudioGeneratorMP3.h"
#include "AudioOutputI2SNoDAC.h"
//#include <FS.h>
AudioGeneratorMP3 *mp3;
AudioFileSourceSPIFFS *file;
AudioOutputI2SNoDAC *out;
#define KEY 0 // 按键
#define LED 2 // 按键
int switchVal = 1;
int BK;
int id;
int ff;
void setup()
{
Serial.begin(115200);
delay(1000);
SPIFFS.begin();
{
Dir dir = SPIFFS.openDir("/");
while (dir.next()) {
String fileName = dir.fileName();
size_t fileSize = dir.fileSize();
Serial.print( fileName );
Serial.println(" // ");
Serial.println( fileSize );
Serial.println(" KB");
}
Serial.println("===========");
}
delay(1000);
out = new AudioOutputI2SNoDAC();
mp3 = new AudioGeneratorMP3();
pinMode( KEY ,INPUT_PULLUP); //定义KEY1为带上拉输入引脚
// pinMode(keys,INPUT); // 输入引脚
pinMode( LED , OUTPUT); //
digitalWrite( LED , 0 );
Serial.println(" MP3 OPEN ");
}
void loop()
{
switchVal = digitalRead( KEY );
if( BK != switchVal)
{
Serial.println(switchVal);
id++;
if(id>=2)
id=0;//0.1
ff=1;
}
BK = switchVal;
if(ff==1)
{
ff=0;
if(id==0)
{
}
if(id==1)
{
}
}
//===================================================
if (mp3->isRunning())
{
digitalWrite( LED , 0 );
// 是否在播放
if (!mp3->loop())
{ // 是否播放完了
mp3->stop(); // 停止播放
delete file;
delete mp3;
mp3 = new AudioGeneratorMP3();
}
}
else
{
digitalWrite( LED , 1 );
if (switchVal == 0)
{
// 开关接通为低电平
file = new AudioFileSourceSPIFFS("/hello.mp3"); // 初始化音频文件
Serial.printf("MP3 done\n");
delay(1000);
mp3->begin(file, out); // 开始播放文件
}
}
}

复制代码

dujq · 发表于 2020-5-4 09:06:59

楼主好，这个不错啊

人艰不拆了 · 发表于 2020-5-4 10:31:40

这个我也试了，没编译过去，就没管了:tongue:

zxy882266 · 发表于 2020-5-4 10:37:51

没加3级管放大可以推动？库都下了，一直在折腾屏就没搞

mckk520 · 发表于 2020-5-4 10:49:06

zxy882266 发表于 2020-5-4 10:37
没加3级管放大可以推动？库都下了，一直在折腾屏就没搞

加三极管直流成分太大，搞坏我一个喇叭，直接加电容隔离，送功放，声音马马虎虎，底噪太大，8266选择160mhz

mckk520 · 发表于 2020-5-4 12:34:55

人艰不拆了发表于 2020-5-4 10:31
这个我也试了，没编译过去，就没管了

ADRUINO安装最新版，8266用2.50那个版本，WIN7系统，保证你什么库都能完美通过

digitking · 发表于 2020-5-4 19:08:18

我用过这个，能用。省了一个adc呢。真心不错

人艰不拆了 · 发表于 2020-5-4 19:11:55

mckk520 发表于 2020-5-4 12:34
ADRUINO安装最新版，8266用2.50那个版本，WIN7系统，保证你什么库都能完美通过 ...

哈哈，原来我用的是2.6几的版本:handshake:

skyrusher · 发表于 2020-5-4 19:26:56

:smile:看看这个：
http://electronics.inf.ua/P40.html
MP3编码的在线电台都能放，清单可自行编辑，拿D1Mini刷进去输出串接100uf电容试了试效果还不错，只是界面是俄语且没提供源码。

mckk520 · 发表于 2020-5-5 07:47:08

skyrusher 发表于 2020-5-4 19:26
看看这个：
http://electronics.inf.ua/P40.html
MP3编码的在线电台都能放，清单可自行编辑，拿D1Mi ...

这个还真不错，老毛子的，要是有源码就好了自己修改一下

mckk520 · 发表于 2020-5-5 15:37:20

8266 网络电台收听，
。
====================

编程后用WEB打开8266设置页面，

https://www.radio.pervii.com/zh/Asian.htm
在这个网站立找到喜欢听的电台地址，传到8266里面，就可以听在线电台了，
==========================

，
，
，
，
，
，

、、、、、、、、、、、、、、、、、、

/*
WebRadio Example
Very simple HTML app to control web streaming
Copyright (C) 2017 Earle F. Philhower, III
This program is free software: you can redistribute it and/or modify
it under the terms of the GNU General Public License as published by
the Free Software Foundation, either version 3 of the License, or
(at your option) any later version.
This program is distributed in the hope that it will be useful,
but WITHOUT ANY WARRANTY; without even the implied warranty of
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
GNU General Public License for more details.
You should have received a copy of the GNU General Public License
along with this program. If not, see <http://www.gnu.org/licenses/>.
*/
#include <Arduino.h>
#ifdef ESP32
#include <WiFi.h>
#else
#include <ESP8266WiFi.h>
#endif
#include "AudioFileSourceICYStream.h"
#include "AudioFileSourceBuffer.h"
#include "AudioGeneratorMP3.h"
#include "AudioGeneratorAAC.h"
#include "AudioOutputI2S.h"
#include <EEPROM.h>
// Custom web server that doesn't need much RAM
#include "web.h"
// To run, set your ESP8266 build to 160MHz, update the SSID info, and upload.
// Enter your WiFi setup here:
#ifndef STASSID
#define STASSID "TP-LINK_4444"
#define STAPSK "66XXXXXXXX"
#endif
const char* ssid = STASSID;
const char* password = STAPSK;
WiFiServer server(80);
AudioGenerator *decoder = NULL;
AudioFileSourceICYStream *file = NULL;
AudioFileSourceBuffer *buff = NULL;
AudioOutputI2S *out = NULL;
int volume = 100;
char title[64];
char url[96];
char status[64];
bool newUrl = false;
bool isAAC = false;
int retryms = 0;
typedef struct {
char url[96];
bool isAAC;
int16_t volume;
int16_t checksum;
} Settings;
// C++11 multiline string constants are neato...
static const char HEAD[] PROGMEM = R"KEWL(
<head>
<title>ESP8266 Web Radio</title>
<script type="text/javascript">
function updateTitle() {
var x = new XMLHttpRequest();
x.open("GET", "title");
x.onload = function() { document.getElementById("titlespan").innerHTML=x.responseText; setTimeout(updateTitle, 5000); }
x.onerror = function() { setTimeout(updateTitle, 5000); }
x.send();
}
setTimeout(updateTitle, 1000);
function showValue(n) {
document.getElementById("volspan").innerHTML=n;
var x = new XMLHttpRequest();
x.open("GET", "setvol?vol="+n);
x.send();
}
function updateStatus() {var x = new XMLHttpRequest();
x.open("GET", "status");
x.onload = function() { document.getElementById("statusspan").innerHTML=x.responseText; setTimeout(updateStatus, 5000); }
x.onerror = function() { setTimeout(updateStatus, 5000); }
x.send();
}
setTimeout(updateStatus, 2000);
</script>
</head>)KEWL";
static const char BODY[] PROGMEM = R"KEWL(
<body>
ESP8266 Web Radio!
<hr>
Currently Playing: <span id="titlespan">%s</span><br>
Volume: <input type="range" name="vol" min="1" max="150" steps="10" value="%d" onchange="showValue(this.value)"/> <span id="volspan">%d</span>%%
<hr>
Status: <span id="statusspan">%s</span>
<hr>
<form action="changeurl" method="GET">
Current URL: %s<br>
Change URL: <input type="text" name="url">
<select name="type"><option value="mp3">MP3</option><option value="aac">AAC</option></select>
<input type="submit" value="Change"></form>
<form action="stop" method="POST"><input type="submit" value="Stop"></form>
</body>)KEWL";
void HandleIndex(WiFiClient *client)
{
char buff[sizeof(BODY) + sizeof(title) + sizeof(status) + sizeof(url) + 3*2];
Serial.printf_P(PSTR("Sending INDEX...Free mem=%d\n"), ESP.getFreeHeap());
WebHeaders(client, NULL);
WebPrintf(client, DOCTYPE);
client->write_P( PSTR("<html>"), 6 );
client->write_P( HEAD, strlen_P(HEAD) );
sprintf_P(buff, BODY, title, volume, volume, status, url);
client->write(buff, strlen(buff) );
client->write_P( PSTR("</html>"), 7 );
Serial.printf_P(PSTR("Sent INDEX...Free mem=%d\n"), ESP.getFreeHeap());
}
void HandleStatus(WiFiClient *client)
{
WebHeaders(client, NULL);
client->write(status, strlen(status));
}
void HandleTitle(WiFiClient *client)
{
WebHeaders(client, NULL);
client->write(title, strlen(title));
}
void HandleVolume(WiFiClient *client, char *params)
{
char *namePtr;
char *valPtr;
while (ParseParam(¶ms, &namePtr, &valPtr)) {
ParamInt("vol", volume);
}
Serial.printf_P(PSTR("Set volume: %d\n"), volume);
out->SetGain(((float)volume)/100.0);
RedirectToIndex(client);
}
void HandleChangeURL(WiFiClient *client, char *params)
{
char *namePtr;
char *valPtr;
char newURL[sizeof(url)];
char newType[4];
newURL[0] = 0;
newType[0] = 0;
while (ParseParam(¶ms, &namePtr, &valPtr)) {
ParamText("url", newURL);
ParamText("type", newType);
}
if (newURL[0] && newType[0]) {
newUrl = true;
strncpy(url, newURL, sizeof(url)-1);
url[sizeof(url)-1] = 0;
if (!strcmp_P(newType, PSTR("aac"))) {
isAAC = true;
} else {
isAAC = false;
}
strcpy_P(status, PSTR("Changing URL..."));
Serial.printf_P(PSTR("Changed URL to: %s(%s)\n"), url, newType);
RedirectToIndex(client);
} else {
WebError(client, 404, NULL, false);
}
}
void RedirectToIndex(WiFiClient *client)
{
WebError(client, 301, PSTR("Location: /\r\n"), true);
}
void StopPlaying()
{
if (decoder) {
decoder->stop();
delete decoder;
decoder = NULL;
}
if (buff) {
buff->close();
delete buff;
buff = NULL;
}
if (file) {
file->close();
delete file;
file = NULL;
}
strcpy_P(status, PSTR("Stopped"));
strcpy_P(title, PSTR("Stopped"));
}
void HandleStop(WiFiClient *client)
{
Serial.printf_P(PSTR("HandleStop()\n"));
StopPlaying();
RedirectToIndex(client);
}
void MDCallback(void *cbData, const char *type, bool isUnicode, const char *str)
{
const char *ptr = reinterpret_cast<const char *>(cbData);
(void) isUnicode; // Punt this ball for now
(void) ptr;
if (strstr_P(type, PSTR("Title"))) {
strncpy(title, str, sizeof(title));
title[sizeof(title)-1] = 0;
} else {
// Who knows what to do? Not me!
}
}
void StatusCallback(void *cbData, int code, const char *string)
{
const char *ptr = reinterpret_cast<const char *>(cbData);
(void) code;
(void) ptr;
strncpy_P(status, string, sizeof(status)-1);
status[sizeof(status)-1] = 0;
}
#ifdef ESP8266
const int preallocateBufferSize = 5*1024;
const int preallocateCodecSize = 29192; // MP3 codec max mem needed
#else
const int preallocateBufferSize = 16*1024;
const int preallocateCodecSize = 85332; // AAC+SBR codec max mem needed
#endif
void *preallocateBuffer = NULL;
void *preallocateCodec = NULL;
void setup()
{
// First, preallocate all the memory needed for the buffering and codecs, never to be freed
preallocateBuffer = malloc(preallocateBufferSize);
preallocateCodec = malloc(preallocateCodecSize);
if (!preallocateBuffer || !preallocateCodec) {
Serial.begin(115200);
Serial.printf_P(PSTR("FATAL ERROR: Unable to preallocate %d bytes for app\n"), preallocateBufferSize+preallocateCodecSize);
while (1) delay(1000); // Infinite halt
}
Serial.begin(115200);
delay(1000);
Serial.printf_P(PSTR("Connecting to WiFi\n"));
WiFi.disconnect();
WiFi.softAPdisconnect(true);
WiFi.mode(WIFI_STA);
WiFi.begin(ssid, password);
// Try forever
while (WiFi.status() != WL_CONNECTED) {
Serial.printf_P(PSTR("...Connecting to WiFi\n"));
delay(1000);
}
Serial.printf_P(PSTR("Connected\n"));
Serial.printf_P(PSTR("Go to http://"));
Serial.print(WiFi.localIP());
Serial.printf_P(PSTR("/ to control the web radio.\n"));
server.begin();
strcpy_P(url, PSTR("none"));
strcpy_P(status, PSTR("OK"));
strcpy_P(title, PSTR("Idle"));
audioLogger = &Serial;
file = NULL;
buff = NULL;
out = new AudioOutputI2S();
decoder = NULL;
LoadSettings();
}
void StartNewURL()
{
Serial.printf_P(PSTR("Changing URL to: %s, vol=%d\n"), url, volume);
newUrl = false;
// Stop and free existing ones
Serial.printf_P(PSTR("Before stop...Free mem=%d\n"), ESP.getFreeHeap());
StopPlaying();
Serial.printf_P(PSTR("After stop...Free mem=%d\n"), ESP.getFreeHeap());
SaveSettings();
Serial.printf_P(PSTR("Saved settings\n"));
file = new AudioFileSourceICYStream(url);
Serial.printf_P(PSTR("created icystream\n"));
file->RegisterMetadataCB(MDCallback, NULL);
buff = new AudioFileSourceBuffer(file, preallocateBuffer, preallocateBufferSize);
Serial.printf_P(PSTR("created buffer\n"));
buff->RegisterStatusCB(StatusCallback, NULL);
decoder = isAAC ? (AudioGenerator*) new AudioGeneratorAAC(preallocateCodec, preallocateCodecSize) : (AudioGenerator*) new AudioGeneratorMP3(preallocateCodec, preallocateCodecSize);
Serial.printf_P(PSTR("created decoder\n"));
decoder->RegisterStatusCB(StatusCallback, NULL);
Serial.printf_P("Decoder start...\n");
decoder->begin(buff, out);
out->SetGain(((float)volume)/100.0);
if (!decoder->isRunning()) {
Serial.printf_P(PSTR("Can't connect to URL"));
StopPlaying();
strcpy_P(status, PSTR("Unable to connect to URL"));
retryms = millis() + 2000;
}
Serial.printf_P("Done start new URL\n");
}
void LoadSettings()
{
// Restore from EEPROM, check the checksum matches
Settings s;
uint8_t *ptr = reinterpret_cast<uint8_t *>(&s);
EEPROM.begin(sizeof(s));
for (size_t i=0; i<sizeof(s); i++) {
ptr[i] = EEPROM.read(i);
}
EEPROM.end();
int16_t sum = 0x1234;
for (size_t i=0; i<sizeof(url); i++) sum += s.url[i];
sum += s.isAAC;
sum += s.volume;
if (s.checksum == sum) {
strcpy(url, s.url);
isAAC = s.isAAC;
volume = s.volume;
Serial.printf_P(PSTR("Resuming stream from EEPROM: %s, type=%s, vol=%d\n"), url, isAAC?"AAC":"MP3", volume);
newUrl = true;
}
}
void SaveSettings()
{
// Store in "EEPROM" to restart automatically
Settings s;
memset(&s, 0, sizeof(s));
strcpy(s.url, url);
s.isAAC = isAAC;
s.volume = volume;
s.checksum = 0x1234;
for (size_t i=0; i<sizeof(url); i++) s.checksum += s.url[i];
s.checksum += s.isAAC;
s.checksum += s.volume;
uint8_t *ptr = reinterpret_cast<uint8_t *>(&s);
EEPROM.begin(sizeof(s));
for (size_t i=0; i<sizeof(s); i++) {
EEPROM.write(i, ptr[i]);
}
EEPROM.commit();
EEPROM.end();
}
void PumpDecoder()
{
if (decoder && decoder->isRunning()) {
strcpy_P(status, PSTR("Playing")); // By default we're OK unless the decoder says otherwise
if (!decoder->loop()) {
Serial.printf_P(PSTR("Stopping decoder\n"));
StopPlaying();
retryms = millis() + 2000;
}
}
}
void loop()
{
static int lastms = 0;
if (millis()-lastms > 1000) {
lastms = millis();
Serial.printf_P(PSTR("Running for %d seconds%c...Free mem=%d\n"), lastms/1000, !decoder?' ':(decoder->isRunning()?'*':' '), ESP.getFreeHeap());
}
if (retryms && millis()-retryms>0) {
retryms = 0;
newUrl = true;
}
if (newUrl) {
StartNewURL();
}
PumpDecoder();
char *reqUrl;
char *params;
WiFiClient client = server.available();
PumpDecoder();
char reqBuff[384];
if (client && WebReadRequest(&client, reqBuff, 384, &reqUrl, ¶ms)) {
PumpDecoder();
if (IsIndexHTML(reqUrl)) {
HandleIndex(&client);
} else if (!strcmp_P(reqUrl, PSTR("stop"))) {
HandleStop(&client);
} else if (!strcmp_P(reqUrl, PSTR("status"))) {
HandleStatus(&client);
} else if (!strcmp_P(reqUrl, PSTR("title"))) {
HandleTitle(&client);
} else if (!strcmp_P(reqUrl, PSTR("setvol"))) {
HandleVolume(&client, params);
} else if (!strcmp_P(reqUrl, PSTR("changeurl"))) {
HandleChangeURL(&client, params);
} else {
WebError(&client, 404, NULL, false);
}
// web clients hate when door is violently shut
while (client.available()) {
PumpDecoder();
client.read();
}
}
PumpDecoder();
if (client) {
client.flush();
client.stop();
}
}

复制代码

====================

jjbboox · 发表于 2020-5-5 22:09:24

[Arduino] 用Esp32做了一个高保真音乐播放器，I2S直通解码器输出(Flac wav mp3)

用ESP32可以播放SD卡上的FLAC

skyrusher · 发表于 2020-5-13 11:21:00

mckk520 发表于 2020-5-5 15:37
8266 网络电台收听，
。
====================

:handshake::victory:已收下并刷入8266.

msold5 · 发表于 2020-5-13 17:37:23

一直没注意过，8266或者ESP32能不能删除SD卡里的MP3歌曲？我的歌太杂太多，想弄个不好听就按个键来删除的播放器，想了很久了一直没动手。

jjbboox · 发表于 2020-5-14 08:13:03

msold5 发表于 2020-5-13 17:37
一直没注意过，8266或者ESP32能不能删除SD卡里的MP3歌曲？我的歌太杂太多，想弄个不好听就按个键来删除的 ...

可以
和播放没啥关系，直接调用SD.remove(filename)就能删除文件了。

msold5 · 发表于 2020-5-14 15:38:33

jjbboox 发表于 2020-5-14 08:13
可以
和播放没啥关系，直接调用SD.remove(filename)就能删除文件了。

这个出来的音质比普通车载MP3如何？

jjbboox · 发表于 2020-5-14 16:14:51

本帖最后由 jjbboox 于 2020-5-14 16:17 编辑

msold5 发表于 2020-5-14 15:38
这个出来的音质比普通车载MP3如何？

我不是楼主

楼主是用PWM输出直接驱动喇叭的，音质肯定是比不了车机的。

不过Esp8266Audio这个库支持I2S无损数字输出的。
如果改用I2S直通解码器解码输出的话，音质取决于后级的解码芯片。
用好一点的解码芯片的话，音质绝不会比车机差的。

你可以去看下面的视频，用解码器播放wav，Flac，后半段通过网页控制的部分录音效果比较好。
https://www.acfun.cn/v/ac12678422?shareUid=12663753